Sql Server數(shù)據(jù)庫(kù)類似正則表達(dá)式的字符處理問(wèn)題

2019-02-10 16:39:38 來(lái)源：互聯(lián)網(wǎng)作者：張騫 人氣： 次閱讀 783 條評(píng)論

SQL Serve提供了簡(jiǎn)單的字符模糊匹配功能，比如：like, patindex，不過(guò)對(duì)于某些字符處理場(chǎng)景還顯得并不足夠，日常碰到的幾個(gè)問(wèn)題有：...

SQL Serve提供了簡(jiǎn)單的字符模糊匹配功能，比如：like, patindex，不過(guò)對(duì)于某些字符處理場(chǎng)景還顯得并不足夠，日常碰到的幾個(gè)問(wèn)題有：

1. 同一個(gè)字符/字符串，出現(xiàn)了多少次

2. 同一個(gè)字符，第N次出現(xiàn)的位置

3. 多個(gè)相同字符連續(xù)，合并為一個(gè)字符

4. 是否為有效IP/身份證號(hào)/手機(jī)號(hào)等 

一. 同一個(gè)字符/字符串，出現(xiàn)了多少次

同一個(gè)字符，將其替換為空串，即可計(jì)算

  1. declare @text varchar(1000)
  2. declare @str varchar(10)
  3. set @text = 'ABCBDBE'
  4. set @str = 'B'
  5. select len(@text) - len(replace(@text,@str,''))

同一個(gè)字符串，仍然是替換，因?yàn)槭嵌鄠€(gè)字符，方法1替換后需要做一次除法；方法2替換時(shí)增加一個(gè)字符，則不需要

  1. --方法1
  2. declare @text varchar(1000)
  3. declare @str varchar(10)
  4. set @text = 'ABBBCBBBDBBBE'
  5. set @str = 'BBB'
  6. select (len(@text) - len(replace(@text,@str,'')))/len(@str)
  7. --方法2
  8. declare @text varchar(1000)
  9. declare @str varchar(10)
  10. set @text = 'ABBBCBBBDBBBE'
  11. set @str = 'BBB'
  12. select len(replace(@text,@str,@str+'_')) - len(@text)

二. 同一個(gè)字符/字符串，第N次出現(xiàn)的位置

SQL SERVER定位字符位置的函數(shù)為CHARINDEX：

CHARINDEX ( expressionToFind , expressionToSearch [ , start_location ] )

可以從指定位置起開(kāi)始檢索，但是不能取第N次出現(xiàn)的位置，需要自己寫(xiě)SQL來(lái)補(bǔ)充，有以下幾種思路：

1. 自定義函數(shù), 循環(huán)中每次為charindex加一個(gè)計(jì)數(shù)，直到為N

  1. if object_id('NthChar','FN') is not null
  2.   drop function Nthchar
  3. GO
  4. create function NthChar
  5. (
  6. @source_string as nvarchar(4000),
  7. @sub_string  as nvarchar(1024),
  8. @nth      as int
  9. )
  10. returns int
  11. as
  12. begin
  13.   declare @postion int
  14.   declare @count  int
  15.   set @postion = CHARINDEX(@sub_string, @source_string)
  16.   set @count = 0
  17.   while @postion > 0
  18.   begin
  19.     set @count = @count + 1
  20.     if @count = @nth
  21.     begin
  22.       break
  23.     end
  24.     set @postion = CHARINDEX(@sub_string, @source_string, @postion + 1)
  25.   End
  26.   return @postion
  27. end
  28. GO
  29. --select dbo.NthChar('abcabc','abc',2)
  30. --4

2. 通過(guò)CTE，對(duì)待處理的整個(gè)表字段操作, 遞歸中每次為charindex加一個(gè)計(jì)數(shù)，直到為N

  1. if object_id('tempdb..#T') is not null
  2.   drop table #T
  3. create table #T
  4. (
  5. source_string nvarchar(4000)
  6. )
  7. insert into #T values (N'我們我們')
  8. insert into #T values (N'我我哦我')
  9. declare @sub_string nvarchar(1024)
  10. declare @nth    int
  11. set @sub_string = N'我們'
  12. set @nth = 2
  13. ;with T(source_string, starts, pos, nth)
  14. as (
  15.   select source_string, 1, charindex(@sub_string, source_string), 1 from #t
  16.   union all
  17.   select source_string, pos + 1, charindex(@sub_string, source_string, pos + 1), nth+1 from T
  18.   where pos > 0
  19. )
  20. select
  21.   source_string, pos, nth
  22. from T
  23. where pos <> 0
  24.  and nth = @nth
  25. order by source_string, starts
  26. --source_string  pos  nth
  27. --我們我們  3  2

3. 借助數(shù)字表 (tally table)，到不同起點(diǎn)位置去做charindex，需要先自己構(gòu)造個(gè)數(shù)字表

  1. --numbers/tally table
  2. IF EXISTS (select * from dbo.sysobjects where id = object_id(N'[dbo].[Numbers]') and OBJECTPROPERTY(id, N'IsUserTable') = 1)
  3.   DROP TABLE dbo.Numbers
  4. --===== Create and populate the Tally table on the fly
  5.  SELECT TOP 1000000
  6.     IDENTITY(int,1,1) AS number
  7.   INTO dbo.Numbers
  8.   FROM master.dbo.syscolumns sc1,
  9.     master.dbo.syscolumns sc2
  10. --===== Add a Primary Key to maximize performance
  11.  ALTER TABLE dbo.Numbers
  12.     ADD CONSTRAINT PK_numbers_number PRIMARY KEY CLUSTERED (number)
  13. --===== Allow the general public to use it
  14.  GRANT SELECT ON dbo.Numbers TO PUBLIC
  15. --以上數(shù)字表創(chuàng)建一次即可，不需要每次都重復(fù)創(chuàng)建
  16. DECLARE @source_string  nvarchar(4000),
  17.     @sub_string    nvarchar(1024),
  18.     @nth       int
  19. SET @source_string = 'abcabcvvvvabc'
  20. SET @sub_string = 'abc'
  21. SET @nth = 2
  22. ;WITH T
  23. AS
  24. (     
  25. SELECT ROW_NUMBER() OVER(ORDER BY number) AS nth,
  26.     number AS [Position In String]
  27.  FROM dbo.Numbers n
  28.  WHERE n.number <= LEN(@source_string) 
  29.   AND CHARINDEX(@sub_string, @source_string, n.number)-number = 0
  30.   ----OR
  31.   --AND SUBSTRING(@source_string,number,LEN(@sub_string)) = @sub_string
  32. )
  33. SELECT * FROM T WHERE nth = @nth

4. 通過(guò)CROSS APPLY結(jié)合charindex，適用于N值較小的時(shí)候，因?yàn)镃ROSS APPLY的次數(shù)要隨著N的變大而增加，語(yǔ)句也要做相應(yīng)的修改

  1. declare @T table
  2. (
  3. source_string nvarchar(4000)
  4. )
  5. insert into @T values
  6. ('abcabc'),
  7. ('abcabcvvvvabc')
  8. declare @sub_string nvarchar(1024)
  9. set @sub_string = 'abc'
  10. select source_string,
  11.     p1.pos as no1,
  12.     p2.pos as no2,
  13.     p3.pos as no3
  14. from @T
  15. cross apply (select (charindex(@sub_string, source_string))) as P1(Pos)
  16. cross apply (select (charindex(@sub_string, source_string, P1.Pos+1))) as P2(Pos)
  17. cross apply (select (charindex(@sub_string, source_string, P2.Pos+1))) as P3(Pos)

5. 在SSIS里有內(nèi)置的函數(shù)，但T-SQL中并沒(méi)有

  1. --FINDSTRING in SQL Server 2005 SSIS
  2. FINDSTRING([yourColumn], "|", 2),
  3. --TOKEN in SQL Server 2012 SSIS
  4. TOKEN(Col1,"|",3)

注：不難發(fā)現(xiàn)，這些方法和字符串拆分的邏輯是類似的，只不過(guò)一個(gè)是定位，一個(gè)是截取，如果要獲取第N個(gè)字符左右的一個(gè)/多個(gè)字符，有了N的位置，再結(jié)合substring去截取即可；

三. 多個(gè)相同字符連續(xù)，合并為一個(gè)字符

最常見(jiàn)的就是把多個(gè)連續(xù)的空格合并為一個(gè)空格，解決思路有兩個(gè)：

1. 比較容易想到的就是用多個(gè)replace

但是究竟需要replace多少次并不確定，所以還得循環(huán)多次才行

  1. --把兩個(gè)連續(xù)空格替換成一個(gè)空格，然后循環(huán)，直到charindex檢查不到兩個(gè)連續(xù)空格
  2. declare @str varchar(100)
  3. set @str='abc    abc   kljlk   kljkl'
  4. while(charindex(' ',@str)>0)
  5. begin
  6.   select @str=replace(@str,' ',' ')
  7. end
  8. select @str

2. 按照空格把字符串拆開(kāi)

對(duì)每一段拆分開(kāi)的字符串trim或者replace后，再用一個(gè)空格連接，有點(diǎn)繁瑣，沒(méi)寫(xiě)代碼示例，如何拆分字符串可參考：“第N次出現(xiàn)的位置”；

四. 是否為有效IP/身份證號(hào)/手機(jī)號(hào)等

類似IP/身份證號(hào)/手機(jī)號(hào)等這些字符串，往往都有自身特定的規(guī)律，通過(guò)substring去逐位或逐段判斷是可以的，但SQL語(yǔ)句的方式往往性能不佳，建議嘗試正則函數(shù)，見(jiàn)下。

五. 正則表達(dá)式函數(shù)

1. Oracle

從10g開(kāi)始，可以在查詢中使用正則表達(dá)式，它通過(guò)一些支持正則表達(dá)式的函數(shù)來(lái)實(shí)現(xiàn)：

  1. Oracle 10 g
  2. REGEXP_LIKE
  3. REGEXP_REPLACE
  4. REGEXP_INSTR
  5. REGEXP_SUBSTR
  6. Oracle 11g (新增)
  7. REGEXP_COUNT

Oracle用REGEXP函數(shù)處理上面幾個(gè)問(wèn)題：

(1) 同一個(gè)字符/字符串，出現(xiàn)了多少次

  1. select length(regexp_replace('123-345-566', '[^-]', '')) from dual;
  2. select REGEXP_COUNT('123-345-566', '-') from dual; --Oracle 11g

(2) 同一個(gè)字符/字符串，第N次出現(xiàn)的位置

不需要正則，ORACLE的instr可以直接查找位置：

instr('source_string','sub_string' [,n][,m])

n表示從第n個(gè)字符開(kāi)始搜索，缺省值為1，m表示第m次出現(xiàn)，缺省值為1。

select instr('abcdefghijkabc','abc', 1, 2) position from dual;

(3) 多個(gè)相同字符連續(xù)，合并為一個(gè)字符

select regexp_replace(trim('agc f  f '),'\s+',' ') from dual;

(4) 是否為有效IP/身份證號(hào)/手機(jī)號(hào)等

  1. --是否為有效IP
  2. WITH IP
  3. AS(
  4. SELECT '10.20.30.40' ip_address FROM dual UNION ALL
  5. SELECT 'a.b.c.d' ip_address FROM dual UNION ALL
  6. SELECT '256.123.0.254' ip_address FROM dual UNION ALL
  7. SELECT '255.255.255.255' ip_address FROM dual
  8. )
  9. SELECT *
  10. FROM IP
  11. WHERE REGEXP_LIKE(ip_address, '^(([0-9]{1}|[0-9][0-9]|1[0-9][0-9]|2[0-4][0-9]|25[0-5])\.){3}([0-9]{1}|[0-9][0-9]|1[0-9][0-9]|2[0-4][0-9]|25[0-5])$');
  12. --是否為有效身份證/手機(jī)號(hào)，暫未舉例

2. SQL Server

目前最新版本為SQL Server 2017，還沒(méi)有對(duì)REGEXP函數(shù)的支持，需要通用CLR來(lái)擴(kuò)展，如下為CLR實(shí)現(xiàn)REG_REPLACE：

  1. --1. 開(kāi)啟 CLR
  2. EXEC sp_configure 'show advanced options' , '1'
  3. GO
  4. RECONFIGURE
  5. GO
  6. EXEC sp_configure 'clr enabled' , '1'
  7. GO
  8. RECONFIGURE
  9. GO
  10. EXEC sp_configure 'show advanced options' , '0';
  11. GO

 2. 創(chuàng)建 Assembly

--3. 創(chuàng)建 CLR 函數(shù)
CREATE FUNCTION [dbo].[regex_replace](@input [nvarchar](4000), @pattern [nvarchar](4000), @replacement [nvarchar](4000))
RETURNS [nvarchar](4000) WITH EXECUTE AS CALLER, RETURNS NULL ON NULL INPUT
AS
EXTERNAL NAME [RegexUtility].[RegexUtility].[RegexReplaceDefault]
GO
--4. 使用regex_replace替換多個(gè)空格為一個(gè)空格
select dbo.regex_replace('agc f  f ','\s+',' ');

注：通過(guò)CLR實(shí)現(xiàn)更多REGEXP函數(shù)，如果有高級(jí)語(yǔ)言開(kāi)發(fā)能力，可以自行開(kāi)發(fā)；或者直接使用一些開(kāi)源貢獻(xiàn)也行，比如：http://devnambi.com/2016/sql-server-regex/

小結(jié)：

1. 非正則SQL語(yǔ)句的思路，對(duì)不同數(shù)據(jù)庫(kù)往往都適用；

2. 正則表達(dá)式中的規(guī)則(pattern) 在不同開(kāi)發(fā)語(yǔ)言里，有很多語(yǔ)法是相通的，通常是遵守perl或者linux shell中的sed等工具的規(guī)則；

3. 從性能上來(lái)看，通用SQL判斷 > REGEXP函數(shù) > 自定義SQL函數(shù)。

總結(jié)：以上所述是小編給大家介紹的SqlServer類似正則表達(dá)式的字符處理問(wèn)題，希望對(duì)大家有所幫助，如果大家有任何疑問(wèn)請(qǐng)給我留言，小編會(huì)及時(shí)回復(fù)大家的。

您可能感興趣的文章

相關(guān)文章